#!/usr/bin/perl -w

#

#   Copyright (c) International Business Machines  Corp., 2002

#

#   This program is free software;  you can redistribute it and/or modify

#   it under the terms of the GNU General Public License as published by

#   the Free Software Foundation; either version 2 of the License, or (at

#   your option) any later version.

#

#   This program is distributed in the hope that it will be useful, but

#   WITHOUT ANY WARRANTY;  without even the implied warranty of

#   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU

#   General Public License for more details.                 

#

#   You should have received a copy of the GNU General Public License

#   along with this program;  if not, write to the Free Software

#   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA

#

#

# lcov

#

#   This is a wrapper script which provides a single interface for accessing

#   LCOV coverage data.

#

#

# History:

#   2002-08-29 created by Peter Oberparleiter <Peter.Oberparleiter@de.ibm.com>

#                         IBM Lab Boeblingen

#   2002-09-05 / Peter Oberparleiter: implemented --kernel-directory +

#                multiple directories

#   2002-10-16 / Peter Oberparleiter: implemented --add-tracefile option

#   2002-10-17 / Peter Oberparleiter: implemented --extract option

#   2002-11-04 / Peter Oberparleiter: implemented --list option

#   2003-03-07 / Paul Larson: Changed to make it work with the latest gcov 

#                kernel patch.  This will break it with older gcov-kernel

#                patches unless you change the value of $gcovmod in this script

#   2003-04-07 / Peter Oberparleiter: fixed bug which resulted in an error

#                when trying to combine .info files containing data without

#                a test name

#   2003-04-10 / Peter Oberparleiter: extended Paul's change so that LCOV

#                works both with the new and the old gcov-kernel patch

#   2003-04-10 / Peter Oberparleiter: added $gcov_dir constant in anticipation

#                of a possible move of the gcov kernel directory to another

#                file system in a future version of the gcov-kernel patch

#   2003-04-15 / Paul Larson: make info write to STDERR, not STDOUT

#   2003-04-15 / Paul Larson: added --remove option

#   2003-04-30 / Peter Oberparleiter: renamed --reset to --zerocounters

#                to remove naming ambiguity with --remove

#   2003-04-30 / Peter Oberparleiter: adjusted help text to include --remove

#   2003-06-27 / Peter Oberparleiter: implemented --diff

#   2003-07-03 / Peter Oberparleiter: added line checksum support, added

#                --no-checksum

#   2003-12-11 / Laurent Deniel: added --follow option

#   2004-03-29 / Peter Oberparleiter: modified --diff option to better cope with

#                ambiguous patch file entries, modified --capture option to use

#                modprobe before insmod (needed for 2.6)

#   2004-03-30 / Peter Oberparleiter: added --path option

#   2004-08-09 / Peter Oberparleiter: added configuration file support

#

use strict;

use File::Basename; 

use Getopt::Long;

# Global constants

our $lcov_version	= "LTP GCOV extension version 1.4";

our $lcov_url		= "http://ltp.sourceforge.net/coverage/lcov.php";

# Names of the GCOV kernel module

our @gcovmod = ("gcov-prof", "gcov-proc");

# Directory containing gcov kernel files

our $gcov_dir = "/proc/gcov";

# The location of the insmod tool

our $insmod_tool	= "/sbin/insmod";

# The location of the modprobe tool

our $modprobe_tool	= "/sbin/modprobe";

# The location of the rmmod tool

our $rmmod_tool		= "/sbin/rmmod";

# Where to create temporary directories

our $tmp_dir		= "/tmp";

# How to prefix a temporary directory name

our $tmp_prefix		= "tmpdir";

# Prototypes

sub print_usage(*);

sub check_options();

sub userspace_reset();

sub userspace_capture();

sub kernel_reset();

sub kernel_capture();

sub add_traces();

sub read_info_file($);

sub get_info_entry($);

sub set_info_entry($$$$$;$$);

sub add_counts($$);

sub merge_checksums($$$);

sub combine_info_entries($$$);

sub combine_info_files($$);

sub write_info_file(*$);

sub extract();

sub remove();

sub list();

sub get_common_filename($$);

sub read_diff($);

sub diff();

sub system_no_output($@);

sub read_config($);

sub apply_config($);

sub info(@);

sub unload_module($);

sub check_and_load_kernel_module();

sub create_temp_dir();

sub transform_pattern($);

# Global variables & initialization

our @directory;		# Specifies where to get coverage data from

our @kernel_directory;	# If set, captures only from specified kernel subdirs

our @add_tracefile;	# If set, reads in and combines all files in list

our $list;		# If set, list contents of tracefile

our $extract;		# If set, extracts parts of tracefile

our $remove;		# If set, removes parts of tracefile

our $diff;		# If set, modifies tracefile according to diff

our $reset;		# If set, reset all coverage data to zero

our $capture;		# If set, capture data

our $output_filename;	# Name for file to write coverage data to

our $test_name = "";	# Test case name

our $source_dirs = "";

our $quiet = "";	# If set, suppress information messages

our $help;		# Help option flag

our $version;		# Version option flag

our $nochecksum ="";	# If set, don't calculate a checksum for each line

our $convert_filenames;	# If set, convert filenames when applying diff

our $strip;		# If set, strip leading directories when applying diff

our $need_unload;	# If set, unload gcov kernel module

our $temp_dir_name;	# Name of temporary directory

our $cwd = `pwd`;	# Current working directory

our $to_file;		# If set, indicates that output is written to a file

our $follow;		# If set, indicates that find shall follow links

our $diff_path = "";	# Path removed from tracefile when applying diff

our $config;		# Configuration file contents

chomp($cwd);

our $tool_dir = dirname($0);	# Directory where genhtml tool is installed

#

# Code entry point

#

# Add current working directory if $tool_dir is not already an absolute path

if (! ($tool_dir =~ /^\/(.*)$/))

{

	$tool_dir = "$cwd/$tool_dir";

}

# Read configuration file if available

if (-r $ENV{"HOME"}."/.lcovrc")

{

	$config = read_config($ENV{"HOME"}."/.lcovrc");

}

elsif (-r "/etc/lcovrc")

{

	$config = read_config("/etc/lcovrc");

}

if ($config)

{

	# Copy configuration file values to variables

	apply_config({

		"lcov_gcov_dir"		=> \$gcov_dir,

		"lcov_insmod_tool"	=> \$insmod_tool,

		"lcov_modprobe_tool"	=> \$modprobe_tool,

		"lcov_rmmod_tool"	=> \$rmmod_tool,

		"lcov_tmp_dir"		=> \$tmp_dir});

}

# Parse command line options

if (!GetOptions("directory|d|di=s" => \@directory,

		"add-tracefile=s" => \@add_tracefile,

		"list=s" => \$list,

		"kernel-directory=s" => \@kernel_directory,

		"extract=s" => \$extract,

		"remove=s" => \$remove,

		"diff=s" => \$diff,

		"no-checksum" => \$nochecksum,

		"convert-filenames" => \$convert_filenames,

		"strip=i" => \$strip,

		"capture|c" => \$capture,

		"output-file=s" => \$output_filename,

		"test-name=s" => \$test_name,

		"source-dirs=s" => \$source_dirs,

		"zerocounters" => \$reset,

		"quiet" => \$quiet,

		"help" => \$help,

		"version" => \$version,

		"follow" => \$follow,

		"path=s" => \$diff_path

		))

{

	print_usage(*STDERR);

	exit(1);

}

# Check for help option

if ($help)

{

	print_usage(*STDOUT);

	exit(0);

}

# Check for version option

if ($version)

{

	print("$lcov_version\n");

	exit(0);

}

# Normalize --path text

$diff_path =~ s/\/$//;

# Check for valid options

check_options();

# Only --extract, --remove and --diff allow unnamed parameters

if (@ARGV && !($extract || $remove || $diff))

{

	print_usage(*STDERR);

	exit(1);

}

# Check for output filename

$to_file = ($output_filename && ($output_filename ne "-"));

if ($capture)

{

	if (!$to_file)

	{

		# Option that tells geninfo to write to stdout

		$output_filename = "-";

	}

}

# Check for requested functionality

if ($reset)

{

	# Differentiate between user space and kernel reset

	if (@directory)

	{

		userspace_reset();

	}

	else

	{

		kernel_reset();

	}

}

elsif ($capture)

{

	# Differentiate between user space and kernel 

	if (@directory)

	{

		userspace_capture();

	}

	else

	{

		kernel_capture();

	}

}

elsif (@add_tracefile)

{

	add_traces();

}

elsif ($remove)

{

	remove();

}

elsif ($extract)

{

	extract();

}

elsif ($list)

{

	list();

}

elsif ($diff)

{

	if (scalar(@ARGV) != 1)

	{

		die("ERROR: option --diff requires one additional argument!\n");

	}

	diff();

}

info("Done.\n");

exit(0);

# Check for follow option

if ($follow)

{

	$follow = "--follow";

}

#

# print_usage(handle)

#

# Print usage information.

#

sub print_usage(*)

{

	local *HANDLE = $_[0];

	my $tool_name = basename($0);

	print(HANDLE <<END_OF_USAGE);

Usage: $tool_name [OPTIONS]

Use lcov to collect coverage data from either the currently running Linux

kernel or from a user space application. Specify the --directory option to

get coverage data for a user space program.

  -h, --help                      Print this help, then exit

  -v, --version                   Print version number, then exit

  -q, --quiet                     Do not print progress messages

  -z, --zerocounters              Reset all execution counts to zero

  -c, --capture                   Capture coverage data

  -t, --test-name NAME            Specify test name to be stored with data

  -o, --output-file FILENAME      Write data to FILENAME instead of stdout

  -d, --directory DIR             Use .da/.gcda files in DIR instead of kernel

  -f, --follow                    Follow links when searching .da/.gcda files

  -k, --kernel-directory KDIR     Capture kernel coverage data only from KDIR

  -a, --add-tracefile FILE        Add contents of tracefiles

  -e, --extract FILE PATTERN      Extract files matching PATTERN from FILE

  -r, --remove FILE PATTERN       Remove files matching PATTERN from FILE

  -l, --list FILE                 List contents of tracefile FILE

      --diff FILE DIFF            Transform tracefile FILE according to DIFF

      --no-checksum               Do not calculate a checksum for each line

      --convert-filenames         Convert filenames when applying diff

      --strip DEPTH               Strip initial DEPTH directory levels in diff

      --path PATH                 Strip PATH from tracefile when applying diff

See $lcov_url for more information about this tool.

END_OF_USAGE

	;

}

#

# check_options()

#

# Check for valid combination of command line options. Die on error.

#

sub check_options()

{

	my $i = 0;

	# Count occurrence of mutually exclusive options

	$reset && $i++;

	$capture && $i++;

	@add_tracefile && $i++;

	$extract && $i++;

	$remove && $i++;

	$list && $i++;

	$diff && $i++;

	if ($i == 0)

	{

		print(STDERR "Need one of the options -z, -c, -e, -a, -r, -l ".

			     "or --diff\n");

		print_usage(*STDERR);

		exit(2);

	}

	elsif ($i > 1)

	{

		die("ERROR: only one of -z, -c, -e, -a, -r, -l or ".

		    "--diff allowed!\n");

	}

}

#

# userspace_reset()

#

# Reset coverage data found in DIRECTORY by deleting all contained .da files.

#

# Die on error.

#

sub userspace_reset()

{

	my $current_dir;

	my @file_list;

	foreach $current_dir (@directory)

	{

		info("Deleting all .da and .gcda files in $current_dir and ".

		     "subdirectories\n");

		if ($follow)

		{

			@file_list =

				`find $current_dir -follow \\( -name \\*.gcda -o -name \\*.da \\) -type f 2>/dev/null`;

		}

		else

		{

			@file_list =

				`find $current_dir \\( -name \\*.gcda -o -name \\*.da \\) -type f 2>/dev/null`;

		}

		chomp(@file_list);

		foreach (@file_list)

		{

			unlink($_) or die("ERROR: cannot remove file $_!\n");

		}

	}

}

#

# userspace_capture()

#

# Capture coverage data found in DIRECTORY and write it to OUTPUT_FILENAME

# if specified, otherwise to STDOUT.

#

# Die on error.

#

sub userspace_capture()

{

	my @param;

	my $file_list = join(" ", @directory);

	info("Capturing coverage data from $file_list\n");

	@param = ("$tool_dir/geninfo", @directory);

	if ($output_filename)

	{

		@param = (@param, "--output-filename", $output_filename);

	}

	if ($test_name)

	{

		@param = (@param, "--test-name", $test_name);

	}

	if ($follow)

	{

		@param = (@param, "--follow");

	}

	if ($quiet)

	{

		@param = (@param, "--quiet");

	}

	if ($nochecksum)

	{

		@param = (@param, "--no-checksum");

	}

	@param = (@param, "--source-dirs", $source_dirs);

	system(@param);

	exit($? >> 8);

}

#

# kernel_reset()

#

# Reset kernel coverage.

#

# Die on error.

#

sub kernel_reset()

{

	local *HANDLE;

	check_and_load_kernel_module();

	info("Resetting kernel execution counters\n");

	open(HANDLE, ">$gcov_dir/vmlinux") or

		die("ERROR: cannot write to $gcov_dir/vmlinux!\n");

	print(HANDLE "0");

	close(HANDLE);

	# Unload module if we loaded it in the first place

	if ($need_unload)

	{

		unload_module($need_unload);

	}

}

#

# kernel_capture()

#

# Capture kernel coverage data and write it to OUTPUT_FILENAME if specified,

# otherwise stdout.

#

sub kernel_capture()

{

	my @param;

	check_and_load_kernel_module();

	# Make sure the temporary directory is removed upon script termination

	END

	{

		if ($temp_dir_name)

		{

			stat($temp_dir_name);

			if (-r _)

			{

				info("Removing temporary directory ".

				     "$temp_dir_name\n");

				# Remove temporary directory

				system("rm", "-rf", $temp_dir_name)

					and warn("WARNING: cannot remove ".

						 "temporary directory ".

						 "$temp_dir_name!\n");

			}

		}

	}

	# Get temporary directory